project('dog.asonix.git.asonix.owo', 'vala', 'c')

i18n = import('i18n')

add_global_arguments('-DGETTEXT_PACKAGE="@0@"'.format (meson.project_name()), language:'c')

app_files = files(
  'src/Application.vala',
  'src/Daemon.vala',
  'src/MainWindow.vala',
  'src/Data/Command.vala',
  'src/Data/SwitchScene.vala',
  'src/Dialogs/EditCommandDialog.vala',
  'src/Dialogs/NewCommandDialog.vala',
  'src/Dialogs/EditDeckDialog.vala',
  'src/Views/ConfigCommand.vala',
  'src/Views/DeckStack.vala',
  'src/Views/DeckView.vala',
  'src/Views/ObsView.vala',
  'src/Widgets/CommandComboBox.vala',
  'src/Widgets/CommandList.vala',
  'src/Widgets/CommandRow.vala',
  'src/Widgets/DeckList.vala',
  'src/Widgets/DeckItem.vala',
  'src/Widgets/DisconnectedPage.vala',
  'src/Widgets/EmptyConfigPane.vala',
  'src/Widgets/ScenesComboBox.vala'
)

executable(
  meson.project_name(),
  app_files,
  dependencies: [
    dependency('gdk-3.0'),
    dependency('gee-0.8'),
    dependency('gio-2.0'),
    dependency('glib-2.0'),
    dependency('granite'),
    dependency('gtk+-3.0'),
    dependency('json-glib-1.0'),
    dependency('libhandy-1'),
    dependency('pango')
  ],
  install: true
)

i18n.merge_file(
  input: join_paths('data', 'owo.desktop.in'),
  output: meson.project_name() + '.desktop',
  po_dir: join_paths(meson.source_root(), 'po'),
  type: 'desktop',
  install: true,
  install_dir: join_paths(get_option('datadir'), 'applications')
)

i18n.merge_file(
  input: join_paths('data', 'owo.appdata.xml.in'),
  output: meson.project_name() + '.appdata.xml',
  po_dir: join_paths(meson.source_root(), 'po'),
  install: true,
  install_dir: join_paths(get_option('datadir'), 'metainfo')
)

meson.add_install_script('meson/post_install.py')

subdir('po')
subdir('data')